cl_scb_test_io_md5_disable_compare.svh

/// Tests the ability to flush queues and disable compare during runtime for md5 hashed queues.

class cl_scb_test_io_md5_disable_compare extends cl_scb_test_single_scb;
  //-------------------------------------
  // UVM Macros
  //-------------------------------------
  `uvm_component_utils(cl_scb_test_io_md5_disable_compare)

  //-------------------------------------
  // Constructor
  //-------------------------------------
  extern function new(string name = "cl_scb_test_io_md5_disable_compare",
                      uvm_component parent = null);
  extern virtual function void pre_build();
  //-------------------------------------
  // UVM Phase methods
  //-------------------------------------
  extern task run_phase(uvm_phase phase);
endclass : cl_scb_test_io_md5_disable_compare

function cl_scb_test_io_md5_disable_compare::new(string name = "cl_scb_test_io_md5_disable_compare",
                                                 uvm_component parent = null);
  super.new(name, parent);
endfunction : new

function void cl_scb_test_io_md5_disable_compare::pre_build();
  super.pre_build();

  this.syoscb_cfgs.syoscb_cfg[0].set_queue_type(pk_syoscb::SYOSCB_QUEUE_MD5);
endfunction : pre_build

task cl_scb_test_io_md5_disable_compare::run_phase(uvm_phase phase);
  phase.raise_objection(this);

  super.run_phase(phase);

  fork
    for(int unsigned i=0; i<10; i++) begin
      cl_tb_seq_item item1;
      item1 = cl_tb_seq_item::type_id::create("item1");
      item1.int_a = i;
      scb_env.syoscb[0].add_item("Q1", "P1", item1);
    end

    for(int unsigned i=0; i<10; i++) begin
      cl_tb_seq_item item1;
      item1 = cl_tb_seq_item::type_id::create("item1");
      item1.int_a = i;
      scb_env.syoscb[0].add_item("Q2", "P1", item1);
    end
  join

  if(!scb_env.syoscb[0].empty_queues()) begin
    `uvm_error("TEST_ERROR", "All queues not empty 1st time around!");
  end

  scb_env.syoscb[0].compare_control(1'b0);

  fork
    for(int unsigned i=0; i<8; i++) begin
      cl_tb_seq_item item1;
      item1 = cl_tb_seq_item::type_id::create("item1");
      item1.int_a = i;
      scb_env.syoscb[0].add_item("Q1", "P1", item1);
    end

    for(int unsigned i=0; i<7; i++) begin
      cl_tb_seq_item item1;
      item1 = cl_tb_seq_item::type_id::create("item1");
      item1.int_a = i+1000;
      scb_env.syoscb[0].add_item("Q2", "P1", item1);
    end
  join

  scb_env.syoscb[0].flush_queues();

  if(!scb_env.syoscb[0].empty_queues()) begin
    `uvm_error("TEST_ERROR", "All queues not empty 2nd time around!");
  end

  scb_env.syoscb[0].compare_control(1'b1);

  fork
    for(int unsigned i=0; i<10; i++) begin
      cl_tb_seq_item item1;
      item1 = cl_tb_seq_item::type_id::create("item1");
      item1.int_a = i;
      scb_env.syoscb[0].add_item("Q1", "P1", item1);
    end

    for(int unsigned i=0; i<10; i++) begin
      cl_tb_seq_item item1;
      item1 = cl_tb_seq_item::type_id::create("item1");
      item1.int_a = i;
      scb_env.syoscb[0].add_item("Q2", "P1", item1);
    end
  join

  phase.drop_objection(this);
endtask: run_phase